みんなの「教えて(疑問・質問)」にみんなで「答える」Q&Aコミュニティ

こんにちはゲストさん。会員登録(無料)して質問・回答してみよう!

解決済みの質問

ミニロト・ロト6のビジュアル化

どなたかご存じでしたら回答をお願いします。
数字選択式宝くじのミニロトとロト6の抽選結果をエクセルに登録しております。
※()内の数字はボーナス数字です。
【ミニロト】
01 12 13 18 21 (06)

【ロト6】
01 12 23 34 35 43 (07)

上記結果を見やすくするために、本数字には「○」をつけて、ボーナス数字には「●」をつける方法
が知りたいです。

【ミニロト】       01 02 03 04 05 06 07 08 09 10 11 12 13 14 15 16 17 18 19 20 21 22 ・・
01 12 13 18 21 (06) ○         ●           ○○          ○    ○

【ロト6】         01 02 03 04 05 06 07 08 09 10 11 12 13 14 15 16 17 18 19 20 21 22・
01 12 23 34 35 43 (07)○           ●         ○   

使用しているエクセルは2007です。

以上、よろしくお願いします。       

投稿日時 - 2011-09-25 16:32:00

QNo.7033591

すぐに回答ほしいです

質問者が選んだベストアンサー

#2です。
計算速度を上げる方法として、こんな方法もあります。
わかりやすさなら #3:keithinさんの方法でどうぞ。

数字はすべて数値。書式設定で2桁表示とする
ボーナス数字以外は、昇順で並んでいる。という前提のもと

H2セル
=IF($F2=H$1,"●",IF(LOOKUP(H$1,$A2:$E2)=H$1,"○",""))
右へ下へオートフィル
ちょっとしたエラー処理をつけるなら
=IF($F2="","",IF($F2=H$1,"●",IF(LOOKUP(H$1,$A2:$E2)=H$1,"○","")))

ロト6の場合はB列を右クリックして[挿入]すれば数式が変化します。
参考まで

投稿日時 - 2011-09-26 08:09:48

お礼

追加で回答頂きありがとうございます。
試してみます。

投稿日時 - 2011-09-26 20:26:46

ANo.4

このQ&Aは役に立ちましたか?

0人が「このQ&Aが役に立った」と投票しています

回答(4)

ANo.3

添付図:

H2:
=IF(H$1=$F2,"●",IF(COUNTIF($A2:$E2,H$1),"○",""))
右にコピー,下にコピー。

投稿日時 - 2011-09-25 22:14:33

お礼

回答ありがとうございます。
早速、ためしてみます。

投稿日時 - 2011-09-25 23:06:41

ANo.2

01 12 13 18 21 (06)
は1つのセルに入っているのでしょうか?
また、01は全角ですが、決まりはあるのでしょうか?
ミニロトとロト6は混在するのでしょうか?

とりあえず、1つのセルに入っている、全角半角混在
(の前にはスペースがある
ミニロトとロト6は混在しないということでたたき台

B2セル
=IF(TEXT(B$1,"00")=MID(ASC($A2),17,2),"●",IF(ISNA(MATCH(TEXT(B$1,"00"),MID(ASC($A2),{1,4,7,10,13},2),0)),"","○"))
右へ下へオートフィル

投稿日時 - 2011-09-25 21:05:40

補足

ご回答ありがとうございます。
また説明不足で申し訳ありません。
補足させていただきます。

>01 12 13 18 21 (06)
>は1つのセルに入っているのでしょうか?
>また、01は全角ですが、決まりはあるのでしょうか?
>ミニロトとロト6は混在するのでしょうか?
>とりあえず、1つのセルに入っている、全角半角混在
>(の前にはスペースがある

ミニロトの01だけが全角になっていることに気が付きませんでした。
数字は全て半角を想定してます。
また1つのセルに全ての数字が入っているとは想定してませんでした。
5つの本数字とボーナス数字はそれぞれセルに入っている想定です。
また、ボーナス数字は本数字と区別するために便宜上、( )をつけただけです。
なので、実際のエクセル登録時はカッコはありません。

>ミニロトとロト6は混在しないということでたたき台
ミニロトとロトは別シートとして管理しており混在はしません。

投稿日時 - 2011-09-25 21:32:16

ANo.1

◆ご質問の内容とは異なりますが、こんなものを作りましたので参考にしてください
◆当せん条件
1等:申込数字が本数字6個と全て一致
2等:申込数字が本数字5個と一致し、更にボーナス数字1個と一致
3等:申込数字が本数字5個と一致
4等:申込数字が本数字4個と一致
5等:申込数字が本数字3個と一致

G5=IF(COUNT(A5:F5)<6,"",TEXT(MATCH(SUMPRODUCT(COUNTIF($A$2:$F$2,A5:F5))+(SUMPRODUCT(COUNTIF($A$2:$F$2,A5:F5))=5)*COUNTIF(A5:F5,$G$2)*0.5,{6,5.5,5,4,3,2,1,0},0),"[<=5]0等;×"))
★下にコピー

>ロト6の当選早見表で本数字が合えば“赤”で表示、ボーナス数字が合えば“青”で表示
【EXCEL2007】
1)A5:F20の範囲を指定して、
2)リボンの「ホーム」タブ→「スタイル」グループ→「条件付き書式」ボタンを選択して、
3)「新しいルール」→「数式を使用して、書式設定するセルを決定する」の「次の数式を満たす場合に値を書式設定」に
4)=COUNTIF($A$2:$F$2,A5) と入力して、
5)右下の「書式」をクリックして、「塗りつぶし」で赤色を指定して、OK
6)もう一度、2)リボンの「ホーム」タブ→「スタイル」グループ→「条件付き書式」ボタンを選択して、
7)「新しいルール」→「数式を使用して、書式設定するセルを決定する」の「次の数式を満たす場合に値を書式設定」に
8)=A5=$G$2 と入力して、
9)右下の「書式」をクリックして、「塗りつぶし」で青色を指定して、OK

投稿日時 - 2011-09-25 18:32:26

お礼

当選チェッカーですね。
網かけもされて見やすいですね。
こんなに当たると何もいう事ないんですがね。。(笑)
ありがとうございます。

投稿日時 - 2011-09-25 19:06:42

あなたにオススメの質問