みんなの「教えて(疑問・質問)」にみんなで「答える」Q&Aコミュニティ

こんにちはゲストさん。会員登録(無料)して質問・回答してみよう!

解決済みの質問

EXCELについて

図の左側のそれぞれの数字の件数を作るのに右側の数字のものを何枚使えばいいか総数を出すのにどのような関数を使えばいいのか教えて下さい。

例えば、7600なら100を1枚と7500を1枚使って作るとき2件ならそれぞれ2枚必要になり、以下同じように11400、15000とそれぞれ組み合わせを作ったとき全部で100は何枚必要かとういう感じです。

投稿日時 - 2011-08-30 23:21:22

QNo.6978854

すぐに回答ほしいです

質問者が選んだベストアンサー

添付図参照
先ず、Sheet1 の表(1件あたりの枚数)を作成
  B列の各セルに数値 0 を入力
  セル C2 に次式を入力して、此れを右方および下方にドラッグ&ペースト
    =INT(($A2-SUMPRODUCT($B$1:B$1,$B2:B2))/C$1)
次に、Sheet2 において、
  セル A2 に式 =Sheet1!A2 を入力して、此れを下方にドラッグ&ペースト
  セル C1 に式 =Sheet1!C1 を入力して、此れを右方にドラッグ&ペースト
  B列に件数を入力
  セル C2 に式 =$B2*Sheet1!C2 入力して、此れを右方および下方にドラッグ&ペースト

投稿日時 - 2011-08-31 02:23:56

このQ&Aは役に立ちましたか?

0人が「このQ&Aが役に立った」と投票しています

回答(6)

ANo.6

#5です。今度は直に出してみました。レイアウトは先程と同じ。
簡単なところから
10000
=SUMPRODUCT(INT(A2:A20/10000),B2:B20)
10000で割り整数化、件数をかけて足す

100
=SUMPRODUCT(MOD(A2:A20,500)/100,B2:B20)
500で割った余りを、100で割り整数化(0~4)、件数をかけて足す

7500
=SUMPRODUCT(INT(MOD(A2:A20,10000)/7500),B2:B20)
10000で割った余りを、7500で割り整数化(0か1)、件数をかけて足す

5000
=SUMPRODUCT(INT(MOD(A2:A20-INT(MOD(A2:A20,10000)/7500)*7500,10000)/5000),B2:B20)
または
=SUMPRODUCT(INT(MOD(A2:A20,10000)/5000)-INT(MOD(A2:A20,10000)/7500),B2:B20)

7500がある場合 元の値から7500を引く。
10000で割った余りを、5000で割り整数化(0か1)、件数をかけて足す。

10000で割った余りを、5000で割り整数化(0か1)、ただし、7500がある場合は1引く
件数をかけて足す。

1000
=SUMPRODUCT(INT(MOD(A2:A20-INT(MOD(A2:A20,10000)/7500)*7500,5000)/1000),B2:B20)
7500上と同様
7500がある場合、元の値から7500を引く。
5000で割った余りを、1000で割り整数化(0~4)、件数をかけて足す。

500
=SUMPRODUCT(INT(MOD(A2:A20-INT(MOD(A2:A20,10000)/7500)*7500,1000)/500),B2:B20)
7500上と同様
7500がある場合 元の値から7500を引く。
1000で割った余りを、500で割り整数化(0か1)、件数をかけて足す。

7500がネックですね

投稿日時 - 2011-08-31 11:39:28

ANo.5

7,500の組合せだと22,500~24,900が少なくなるのかなあ。

難しいことは対応できそうにないので、大きい方から引いていく手段で
J2:J6コピー
C1セルで 形式を選択して貼り付け、[レ]行列を入れ替える

H2セル =INT(A2/H$1)
下へオートフィル
G2セル
=INT(($A2-SUMPRODUCT(H$1:$H$1,H2:$H2))/G$1)
左へ、下へオートフィル

K2セル
=SUMPRODUCT(INDEX($C$2:$H$5,,MATCH($J2,$C$1:$H$1,0)),$B$2:$B$5)
下へオートフィル

投稿日時 - 2011-08-31 07:49:04

ANo.3

画像がうまく添付できませんでしたので、以下にセルの内容をコピーします。

     7600 11400 15000 30000
件数   2    1    4    3    合計枚数
100    1    4    0    0    6
500    0    0    0    0    0
1000   0    1    0    0    1
5000   0    0    1    0    4
7500   1    0    0    0    2
10000   0    1    1    3   14

投稿日時 - 2011-08-31 02:02:17

ANo.2

必ず大きいほうの数字から順に使用するという条件があるなら、以下のようなリストにすれば、各数字の総枚数が表示できます。

B8セル(以下右方向にオートフィル)
=INT(B$1/$A8)

B7セル
=INT((B$1-$A$8*B$8)/$A7)

B6セル
=INT((B$1-$A$8*B$8-$A$7*B$7)/$A6)

B5セル
=INT((B$1-$A$8*B$8-$A$7*B$7-$A$6*B$6)/$A5)

B4セル
=INT((B$1-$A$8*B$8-$A$7*B$7-$A$6*B$6-$A$5*B$5)/$A4)

B3セル
=INT((B$1-$A$8*B$8-$A$7*B$7-$A$6*B$6-$A$5*B$5-$A$4*B$4)/$A3)

F3セル(下方向にオートフィル)
=SUMPRODUCT($B$2:$E$2,B3:E3)

投稿日時 - 2011-08-31 01:37:01

ANo.1

数字の選択の基準が不明確です。

例えばできる限り少ない枚数の組み合わせを選択するという条件の場合でも、15000は10000+5000と7500+7500の2つのパターンがあります。

このようなケースを含めて、数字の選択基準は必ず大きいほうの数字から順に選択するという条件なのでしょうか?

投稿日時 - 2011-08-31 00:54:20

あなたにオススメの質問