みんなの「教えて(疑問・質問)」にみんなで「答える」Q&Aコミュニティ

こんにちはゲストさん。会員登録(無料)して質問・回答してみよう!

解決済みの質問

エクセルで電気料金の計算をしたい

エクセルで電気料金の計算をしたいのですが。
例えば以下の場合
基本料金 契約アンペア50A 1500円
電力量料金表
     (ア)最初の100Kwhまで1Kwh15円
     (イ)100Kwhを超え250Kwhまで1Kwh20円
     (ウ)250Kwhを超える分1Kwh25円

月の使用量
     1月543Kwh
     2月475Kwh
としたら
1月の場合 基本料金1500円
    (ア)100Kwh*15円=1500円
       543Kwh-100Kwh=443Kwh
      100Kwh<(543-100)>250kwh
                      =
    (イ)250Kwh*20円=5000円
       543-100-250=193Kwh
      250<543-100-250
    (ウ)193Kwh*25円=4825円
       
 従って料金は
 基本料金 1500円+(ア)+(イ)+(ウ)で11325円となります。(税金は除く)
これを解決したいのですがどのような関数をどのように駆使すればよいのかわかりませんのでよろしく願います。

投稿日時 - 2007-02-15 13:16:38

QNo.2754547

すぐに回答ほしいです

質問者が選んだベストアンサー

少し勘違いされている所もありますので指摘も踏まえて説明してみます。

100kWhまでの1kWhあたり
 15 x 100 = 1500

100kWhを超え250kWhまでの【150kWhの】1kWhあたり
 20 x (250 - 100) = 3000

250kWhを超えた1kWhあたり
 25 x (使用量 - 250)
 25 x (543 - 250) = 7325

基本料金を加えた料金(燃料調整費/口座振替割引/消費税を含まない)  1500 + 1500 + 3000 + 7325 = 13325

計算式はこうなります。
さて、数式の組み立て方です。
A1に電力量が入力されるとします。

MIN関数で、~までと比較して小さい方を電力量とします。
(ア)MIN(A1,100)
(イ)MIN(A1-100,250-100)
(ウ)A1-250
これに、それぞれの項目がゼロ以下になることを考慮して ゼロ も加えMAX関数で比較します。
(ア)MAX(MIN(A1,100),0)
(イ)MAX(MIN(A1-100,250-100),0)
(ウ)MAX(A1-250,0)
あとはそれぞれの従量分の料金を掛け、基本料金と足し合わせるだけです。
 1500+MAX(MIN(A1,100),0)*15+MAX(MIN(A1-100,250-100),0)*20+MAX(A1-250,0)*25

ちょっと見づらくなっていますが、関数を利用した計算ではこのようになります。
料金表を作成して、それをVLOOKUP関数で抽出しても良いかもしれませんが、
料金表を作るのは面倒ですね。

投稿日時 - 2007-02-15 15:32:21

補足

ご丁寧なご回答ありがとうございます。
100Kwhを超え」250kwhまでと言うことは543-100=443で、この443kwh
から250kwhを減じ…云々…では無いと言うことで…
勘違いしていたんですね。

どうりで幾ら計算しても金額が=にならず・・・
あせっていました。(汗)

関数式の組み立てもおかげ様でわかりました。

ちなみに今回このような質問をさせていただいたのは、
我が家の電力量の把握をし、ガスで電気発電(エコウイル)をした
場合の検討資料を作成中にふと思いつき、
関数によって算出しておけばガス料金の算定にも使えて、
便利と思いついたしだいです。
そのため、噛み砕いた判りやすい説明で本当に助かりました。

投稿日時 - 2007-02-15 18:12:28

ANo.3

このQ&Aは役に立ちましたか?

2人が「このQ&Aが役に立った」と投票しています

回答(6)

ANo.6

◆単価は、「15円」とか「20円」とかでしょうか?
◆ひょっとして、15.02とか円以下はありませんか、端数処理も含めて、当該の電力会社のホームページに計算式はありませんか?
◆そのほうがより正確ではないかと思いますが、いかがでしょうか?

投稿日時 - 2007-02-15 20:40:44

補足

連絡ありがとうございます。
>◆単価は、「15円」とか「20円」とかでしょうか?
>◆ひょっとして、15.02とか円以下はありませんか、端数処理も含めて、当該の電力会社のホームページに計算式はありませんか?
>◆そのほうがより正確ではないかと思いますが、いかがでしょうか?
本来は貴方のご指摘のとおりです。
また電力会社のHPにも計算式が一部掲載されていました。
しかしながら「例題」の様に3段階に分かれた計算式では無かったので、
敢えて皆様方にお伺い致したしだいです。
又ここで特に知りたかったのはエクセル関数を用いての計算式でした。
貴方を除き4名の方からご回答をいただき関数の使い方や種類等々を
ご教授頂いたのでこれからジックリと紐解いて勉強したいと考えております。
この度は連絡ありがとうございます。

投稿日時 - 2007-02-15 21:18:47

=1500+15*IF(A1>100,100,A1)+20*IF(A1>100,IF(A1>250,250-100,A1-100),0)+25*IF(A1>250,A1-250,0)

投稿日時 - 2007-02-15 19:46:14

ANo.4

>計算式のことですが*5の意味は?どのようなことですか・

=1500+15*A1+MAX(A1-100,0)*5+MAX(A1-350,0)*5
=1500+15*A1+MAX(A1-100,0)*(20-15)+MAX(A1-350,0)*(25-20)

1、考え方は、15*A1 ・・・ 使用量*単価15

2、MAX(A1-100,0)*(20-15)
 100Kwh超過分使用量MAX(A1-100,0)*割増料金(20-15)

3、MAX(A1-350,0)*(25-20)
 350Kwh超過分使用量MAX(A1-350,0)*割増料金の割増料金(25-20) 

投稿日時 - 2007-02-15 16:00:56

お礼

度々ご面倒をおかけし申し訳ありませんでした。
なにせ簡単な事を省略されると硬い頭故・・・
なかなか理解するまでに時間がかかり・・・(謝謝)
でもおかげさまで大変参考になりました。
貴重な時間を割いていただき、
ありがとうございまあした。

投稿日時 - 2007-02-15 18:22:14

ANo.2

A1=543として
B1=IF(A1>=250,(A1-250)*25+6000,IF(A1>=100,(A1-100)*20+3000,A1*15+1500))
または
B1=(MAX(A1,250)-250)*25+(MIN(MAX(A1,100),250)-100)*20+MIN(A1,100)*15+1500

前者は、使用量以上の金額に、使用量以下の規定額を加算したもの
後者は、使用量範囲毎に計算して合算したもの

投稿日時 - 2007-02-15 13:43:31

補足

早速のご回答ありがとうございます。
これからエクセルで計算してみます。
取り急ぎの為これにて失礼致します。

投稿日時 - 2007-02-15 14:15:24

ANo.1

質問と、計算式、答えが合わないようですが・・・

>電力量料金表
> (ア)最初の100Kwhまで1Kwh15円
> (イ)100Kwhを超え250Kwhまで1Kwh20円
> (ウ)250Kwhを超える分1Kwh25円

(イ)100Kwhを超える250Kwh分まで1Kwh20円
(100Kwhを超え350Kwhまで1Kwh20円)
ということかな

=1500+15*A1+MAX(A1-100,0)*5+MAX(A1-350,0)*5

1500+1500+5000+4825=12825 になりませんか?

投稿日時 - 2007-02-15 13:42:27

補足

>1500+1500+5000+4825=12825 になりませんか?
 なります。
 すみません私計算ミスをしておりました。
 あわて者で…(謝)

>(100Kwhを超え350Kwhまで1Kwh20円)
ということかな
 そうです、というよりもそのような考え方にしたら判りやすいですね。
 で、計算式のことですが*5の意味は?どのようなことですか・

投稿日時 - 2007-02-15 14:03:44

あなたにオススメの質問